Quiz Answers – Chapter 5

Preface: this post is part of the Bulkify Your Code series.
View Chapter 5 quiz questions without the answers!

Chapter 5 Questions:

1. True or false. There is always a way around any Governor Limit.

2. True or false. Code will not be able to by deployed if it hits Governor Limits.

3. True or false. Without any changes to code, it’s possible for a trigger to hit Governor Limits on one run, and pass Governor Limits on another.

4. An identical search term has been added to a Map for a second time – this time with a different search result. What happens when the Map is searched using this search term?
(a) An error occurs when adding the second result
(b) The first search result is returned
(c) The second search result is returned
(d) Both search results are returned in a search

5. Different search terms are added to a Map – both with the same search result. What happens when the Map is searched?
(a) An error occurs when adding the second result
(b) When searching the first term, an error occurs
(c) When searching the second term, an error occurs
(d) The same search result is returned for both search terms

6. True or false. It’s OK to have SOQL inside a loop if you know 100% you’ll only have one record in the loop.

7. When combining SOQL queries, why is it better to query against a Set of potential values instead of a List?

Chapter 5 Practice Trigger
Write a trigger that populates an “Owner’s Manager” lookup field on opportunities based on the opp owner’s (user’s) standard ManagerId field. Don’t forget the test class!

trigger OMgr on Opportunity (before insert, before update) {
  // Get the set of all owners
  Set<Id> ownerIds = new Set<Id>();
  for (Opportunity opp : Trigger.new) {
    ownerIds.add(opp.OwnerId);
  }
  
  // Create a map of users to managers  
  List<User> users = [SELECT Id, ManagerId 
                       FROM User 
                       WHERE Id IN :ownerIds];
  Map<Id, Id> userToMgr = new Map<Id, Id>();
  for (User u : users) {
    userToMgr.put(u.Id, u.ManagerId);
  }
  
  // Set the opp field to the owner's manager
  for (Opportunity o : Trigger.new) {
    o.Owner_Manager__c = userToMgr.get(o.OwnerId);
  }
}

Test class:

@IsTest
public class TestOMgr {
  static testmethod void testOppMgrs() {
    // Create manager
    User mgr              = new User();
    mgr.Username          = 'govlimitking@gmail.com';
    mgr.Email             = 'govlimitking@gmail.com';
    mgr.FirstName         = 'No';
    mgr.LastName          = 'Worries';
    mgr.Alias             = 'ez';
    mgr.CommunityNickname = 'lifeisgood';
    mgr.ProfileId         = '00ei0000000rTfp';
    mgr.TimeZoneSidKey    = 'GMT';
    mgr.LocaleSidKey      = 'en_US';
    mgr.EmailEncodingKey  = 'ISO-8859-1';
    mgr.LanguageLocaleKey = 'en_US';
    insert mgr;

    // Create user w/above manager
    User owner              = new User();
    owner.Username          = 'govlimitqueen@gmail.com';
    owner.Email             = 'govlimitqueen@gmail.com';
    owner.FirstName         = 'No';
    owner.LastName          = 'Prenup';
    owner.Alias             = 'dollaz';
    owner.CommunityNickname = 'cashmunny';
    owner.ProfileId         = '00ei0000000rTfp';
    owner.TimeZoneSidKey    = 'GMT';
    owner.LocaleSidKey      = 'en_US';
    owner.EmailEncodingKey  = 'ISO-8859-1';
    owner.LanguageLocaleKey = 'en_US';
    owner.ManagerId         = mgr.Id;
    insert owner;
    
    // Create 200 opps to test gov limits
    System.runAs(owner) {
      List<Opportunity> opps = new List<Opportunity>();
      for (Integer i = 0; i < 200; i++) {
        Opportunity o = new Opportunity();
        o.Name        = 'Biggest Deal of All Time';  
        o.Amount      = 10;
        o.CloseDate   = Date.today();
        o.StageName   = 'Prospecting';
        opps.add(o);
      }
      insert opps;
    }
    
    // Make sure everything worked!
    List<Opportunity> newOpps = [SELECT Id, Owner_Manager__c
                                  FROM Opportunity];
    for (Opportunity o : newOpps) {
      System.assertEquals(mgr.Id, o.Owner_Manager__c);
    }
  }
}