Example: How to write an advanced trigger!

Preface: this post is part of the Write Your First Advanced Trigger series.

WARNING: Do not attempt this trigger unless you’re comfortable with Chapter 1 through Chapter 6!

You may not realize it, but you’re about to reach the most important milestone in your coding career!

Frodo Baggins, as he prepares to destroy the Ring and fulfill his life’s destiny!

You’re one step away from knowing how to write an advanced trigger. After destroying this trigger, no other will be impossible for you to slay. All triggers follow the same general pattern!

Here’s this chapter’s trigger. The major differences between this and our pseudo-code is that this code is bulkified and it’s production ready:

// Share an Account with every member of its Territory
trigger ShareTerr on Account (after insert, before update) {

  // Step 1: Create a set of all Zip Codes to evaluate
  Set<String> zips = new Set<String>();
  if (Trigger.isInsert) {
    // For inserted Accounts, all Zip Codes are needed
    for (Account a : Trigger.new) {
      zips.add(a.BillingPostalCode);
    }
  } else if (Trigger.IsUpdate) {
    // For updated Accounts, only evaluate changed Zip Codes
    Set<Id> changedAccs = new Set<Id>();
    for (Account a : Trigger.new) {
      String oldZip = Trigger.oldMap.get(a.Id).BillingPostalCode;
      String newZip = a.BillingPostalCode;
      if (newZip != oldZip) {
        zips.add(newZip);
        changedAccs.add(a.Id);
      }      
    }
    
    // Step 1a: Delete sharing records from old Territories
    List<AccountShare> shares = [SELECT Id FROM AccountShare
                                  WHERE AccountId IN :changedAccs
                                    AND RowCause = 'Manual'];
    delete shares;
  }
  
  // Step 2: Find the matching Territories and Map them
  Map<String, Territory__c> terrMap = 
    new Map<String, Territory__c>();
  List<Territory__c> terrs = [SELECT Id, Zip_Code__c,
                   (SELECT Id, User__c FROM Territory_Members__r)
                                FROM Territory__c
                                WHERE Zip_Code__c IN :zips];
  for (Territory__c terr : terrs) {
    terrMap.put(terr.Zip_Code__c, terr);
  }
  
  // Step 3: Create AccountShares for all Territory Members
  List<AccountShare> shares = new List<AccountShare>();
  for (Account a : Trigger.new) {
    Territory__c terr = terrMap.get(a.BillingPostalCode);
    if (terr != null) {
      for (Territory_Member__c tm : terr.Territory_Members__r) {
        // We won't create one if they're already the owner
        if (tm.User__c != a.OwnerId) {
          AccountShare aShare           = new AccountShare();
          aShare.AccountId              = a.Id;
          aShare.UserOrGroupId          = tm.User__c;
          aShare.AccountAccessLevel     = 'Edit';
          aShare.OpportunityAccessLevel = 'Edit';
          shares.add(aShare);
        }
      }
    }
  }
  insert shares;
}

Folks, that’s all there is to it! It’s not a lot of code if you approach it step-by-step. If you’ve been following the Sfdc99 tutorials in order, you’ve already written similar code to each individual piece of this trigger. This is simply the first time it has all been in one place.

You’ll know this trigger works by clicking on the Sharing button on any Account page to see who the record is shared with and why!

Next post: Example: How to write an advanced test class!