Introduction to the “static” keyword

Preface – This post is part of the Object Oriented Thinking series.

Static is a special, often used keyword modifier in Apex that’s important enough to get its own post.

Steve Jobs described objects as “living, breathing things that have knowledge inside them about how to do things and have memory inside them so they can remember.” Static is basically the opposite. Static things are lifeless and operate independently from any environment.

Static variables are variables that belong to an overall class, not a particular object of a class. Think of a static variable to be like a global variable – its value is shared across your entire org. Any particular object’s properties or values are completely irrelevant when using static.

// This example illustrates static vs. non-static variables
public class DarkJedi {
  public Integer        jedisDefeated = 0;
  public static Integer totalJedisDefeated = 0;
  public void executeJedi() {
    // Wooosh vvvzzztt! AAHHHHH!
    jedisDefeated      = jedisDefeated + 1;
    totalJedisDefeated = totalJedisDefeated + 1;
  }
} 

// Elsewhere...
DarkJedi marcBenioff  = new DarkJedi();
DarkJedi larryEllison = new DarkJedi();

marcBenioff.executeJedi();
larryEllison.executeJedi();

System.debug(marcBenioff.jedisDefeated);   // This is 1
System.debug(larryEllison.jedisDefeated);  // This is 1

// Access static variables only by class name, not object name
System.debug(DarkJedi.totalJedisDefeated); // This is 2

Static methods, similarly, are methods that act globally and not in the context of a particular object of a class. Being global, static methods only have access to its provided inputs and other static (global) variables.

// This example illustrates static vs. non-static methods
public class LightJedi {
  public void slashLightsaber() {
    // Vooooom!
  }

  public static String getJediCode() {
    String code  = 'There is no emotion, there is peace.';
           code += 'There is no ignorance, there is knowledge.';
           code += 'There is no passion, there is serenity.';
           code += 'There is no death, there is the Force.';
    return code;
  }
  
  public static String describeRank(String rank) {
    String description;
    if (rank == 'Initiate') {
      description = 'Jedi hopeful';
    } else if (rank == 'Padawan') {
      description = 'Apprentice of a Jedi Knight';
    } else if (rank == 'Knight') {
      description = 'Completed the Jedi Trials';
    } else if (rank == 'Master') {
      description = 'David Liu';
    }
    return description;
  }
}

// Elsewhere...
LightJedi davidLiu = new LightJedi();

// Non-static methods require an object for context
davidLiu.slashLightsaber();
// Static methods aren't related to a particular object
LightJedi.getJediCode();
// You don't even use an object to call a static method!
System.debug(LightJedi.describeRank('Master')); // David Liu

Other examples of non-static methods include lead convert, delete opportunity, and edit contact. Other examples of static methods could be convert millimeters to centimeters, subtract two numbers, and convert String to uppercase.

On the fence to use static or non-static in your particular scenario? Go non-static – objects are powerful constructs and there’s no use limiting yourself using static if in doubt. Static, as you’ll soon see however, has important and precise use cases!

Next post: Example: Using static to prevent triggers from running twice!